Securer file sharing with Dropbox

It automates the workflow these guys suggested:
http://www.practicallyefficient.com/2011/03/11/securer-file-sharing-with-dropbox/
http://www.kungfugrippe.com/post/3786441300/dbox-trick

What it does:
- take files/folders and create a zip-file
- save the zip-file in your Public folder of dropbox
- set zip-file name: "$randomStuff_$timestamp.zip"
- copy the URL of the zip-file to your clipboard so you can use it anywhere you like pressing "cmd + V"

What it does not do:
- password protect the files (this would require somebody who actually knows shell-scripting :))
- handle folders correctly: it just takes the content of the folder (no directory structure inside the resulting zip-file)

It relies on you to:
- set the properties correctly (see below)
- set up a Hazel rule to remove the file automatically from Dropbox

Helpful:
- the timestamp can be converted to a human readable format typing "date -r timestamp" in terminal (without the "" and replacing timestamp with the number from the filename)

Usage:
- I would suggest you save it as an App so you can:
- open files with it (also using your launcher of choice, I use Alfred.app - highly recommendable and it's free)
- drop files on it

version 1.0: Original release
*)

--in the format of "Path:To:Your:Dropbox:Public:Folder:"
property dropboxPublicFolder : ((path to home folder) as string) & "Dropbox:Public:"
-- change the number in this link
property dropboxURL : "https://dl.getdropbox.com/u/123456/"
-- This text is copied to clipboard together with your url, just put "" to have no additionalText resulting in just the URL"
property additionalText : "For security reasons the file is not attached to this email and will only be available for download for the next 3 day under the above link"
-- true: shows message when finished / false: no message
property showMessage : true

--------------editing below this line at your own risk-------------------

on run
set theFileList to choose file with multiple selections allowed
handle(theFileList)
end run

on open theFileList
handle(theFileList)
end open

on multiDelimSplit(theString, theDelims)
try
set oldDelim to AppleScript's text item delimiters
set theList to {theString}
repeat with aDelim in theDelims
set AppleScript's text item delimiters to aDelim
set newList to {}
repeat with anItem in theList
set newList to newList & text items of anItem
end repeat
set theList to newList
end repeat
set AppleScript's text item delimiters to oldDelim
on error
set AppleScript's text item delimiters to oldDelims
end try
return theList
end multiDelimSplit

on randomString()
set x to {}
repeat (random number from 10 to 15) times
set end of x to some item of "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"
if (random number from 0 to 1) is equal to 1 then
set end of x to some item of "0123456789"
end if
end repeat
return x as string
end randomString

on handle(fileList)
set toClipboard to ""
set unixTimestamp to do shell script "date +%s"

set termFiles to ""
repeat with each in fileList
set termFiles to termFiles & space & quoted form of POSIX path of each
end repeat

set myPath to quoted form of POSIX path of dropboxPublicFolder
set zipName to my randomString() & "_" & unixTimestamp & ".zip"
set zipFile to myPath & zipName

do shell script "zip -r -j " & zipFile & termFiles & " -x \\*.DS_Store"

tell application "Finder" to set the clipboard to dropboxURL & zipName & return & additionalText